快速切换本地连接和无线网工具

每日一学网站长 9个月前 ( 03-24 ) 4条评论

默认

公司一直用的是无线，有带宽限制，自己单独有根外网的线，平时也连在电脑上，所以平时想上外网的时候就断开无线，再连接有线。用内网的时候又得切回来！只能说两个字，麻烦！！人懒嘛！所以研究了下，写了个批处理，一键式开启关闭无线或有线！

图片.png

下面帖代码，注意，其中最重要的是两行代码

netsh interface set interface name="WLAN" admin=disabled
netsh interface set interface name="以太网" admin=enabled
这里面的wlan和以太网是以电脑里面的连接名称为准，比如说我的电脑里面是wlan和以太网那么就写wlan和以太网，如果是wifi和本地连接就得改成wifi和本地连接

图片.png

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
@echo off
color 3e
title ------快速切换网络------
:begin
echo -------------------------------------------------------------
echo.
echo.
echo                  ------------------------------
echo                     快速切换网络
echo                  ------------------------------
echo.
echo.
echo 1、关闭wifi，启用本地连接
echo 2、启用wifi,禁用本地连接
echo 3、启用wifi,启用本地连接
echo 4、禁用所有连接

echo 5、退出
echo -------------------------------------------------------------
set /p num=请选择要执行的操作序号：
if "%num%"=="1" (goto Num1)
if "%num%"=="2" (goto Num2)
if "%num%"=="3" (goto Num3)
if "%num%"=="4" (goto Num4)
if "%num%"=="5" (goto Num5)
:Num1
cls
echo 你输入的编号是%num%
netsh interface set interface name="WLAN" admin=disabled
netsh interface set interface name="以太网" admin=enabled

goto begin
:Num2
cls
echo 你输入的编号是%num%
netsh interface set interface name="WLAN" admin=enabled
netsh interface set interface name="以太网" admin=disabled
goto begin

:Num3
cls
echo 你输入的编号是%num%
netsh interface set interface name="WLAN" admin=enabled
netsh interface set interface name="以太网" admin=enabled
goto begin

:Num4
cls
echo 你输入的编号是%num%
netsh interface set interface name="WLAN" admin=disabled
netsh interface set interface name="以太网" admin=disabled
goto begin

:Num5
exit